home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / SORT / SORT1.ASM next >
Assembly Source File  |  1989-01-24  |  1KB  |  48 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAIMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Last Update 11 Sep 87   Version 1.0
  7. ;
  8. ; Sorting by Straight Selection
  9. ;
  10. sort1   macro   ARRAY,N_ITEMS   
  11. sort1   ident   1,1
  12.  
  13. ; reference: Niklaus Writh, "Algorithms + Data Structures = Programs", 
  14. ;            Prentice-Hall, 1976, Program 2.3, page 64
  15. ;
  16. ; ARRAY = location of an array of numbers in X memory space, 
  17. ;         first item is located at ARRAY.
  18. ; N_ITEMS = number of items in the array
  19. ;
  20. ; register usage:
  21. ;       r0=(j)          r1=(k)          r2=(i)
  22. ;       r4=j'           n1=-2 offset
  23. ;       a=x             b       
  24. ;       y0              
  25. ;       uses 4 words of stack
  26. ;       assumes m0..m2 = $ffff
  27. ;
  28.         move            #N_ITEMS,r4        
  29.         move            #ARRAY,r2
  30.         move            #-2,n1  
  31.  
  32.         do      #N_ITEMS-1,_loop2
  33.         lua     (r2)+,r0
  34.         move    x:(r2),a        y:(r4)-,b
  35.         move    x:(r0)+,b 
  36.         move    r0,r1
  37.  
  38.         do      r4,_loop1
  39.         cmp     b,a     x:(r0)+,b       b,y0
  40.         tge     y0,a    r0,r1
  41. _loop1
  42.         move    x:(r2),y0
  43.         move    a,x:(r2)+
  44.         move    y0,x:(r1+n1)
  45. _loop2
  46.         endm
  47.  
  48.